<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
    xmlns:foaf="http://xmlns.com/foaf/0.1/"
    xmlns:rdfs="http://www.w3.org/2000/01/rdf-schema#"
    xmlns:rss="http://purl.org/rss/1.0/">

<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/">
<rdf:RDF>
    <xsl:apply-templates/>
</rdf:RDF>
</xsl:template>

<xsl:template match="head"/>

<xsl:template match="outline">
    <xsl:variable name="id" select="generate-id(.)"/>
    <xsl:variable name="theURL">
        <xsl:choose>
        <xsl:when test="starts-with(@url, 'http://')">
            <xsl:value-of select="@url"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="concat('http://', @url)"/>
        </xsl:otherwise>
        </xsl:choose>
    </xsl:variable>
    <foaf:Person rdf:nodeID="{$id}">

        <foaf:name><xsl:value-of select="@text"/></foaf:name>

        <xsl:if test="$theURL != 'http://'">
            <foaf:weblog rdf:resource="{$theURL}"/>
        </xsl:if>

        <xsl:if test="@xmlUrl != ''">
          <rdfs:seeAlso>
            <rss:channel rdf:about="{@xmlUrl}">
                <foaf:maker rdf:nodeID="{$id}" />
            </rss:channel>
          </rdfs:seeAlso>
        </xsl:if>


    </foaf:Person>
</xsl:template>

</xsl:stylesheet>